피지컬 머티리얼 시스템

/**
*  발자국 소리를 재생하라는 C++ 영역에서의 이벤트
**/
event PlayFootStepSound(int FootDown)
{
   local vector PawnLoc;
   local float CurrHeight;

   local Actor TraceActor;

   local vector out_HitLocation;
   local vector out_HitNormal;
   local vector TraceDest;
   local vector TraceStart;
   local vector TraceExtent;
   local TraceHitInfo HitInfo;

   // 자자 여기서 바닥까지 추적을 해줘야 겠습니다! (kk here we need to do a tracez0r down down into the ground baby!)
   // 주: 이건 결국 C++ 영역으로 넘어갈 겁니다.
   PawnLoc = self.Location;
   CurrHeight = self.GetCollisionHeight();

   TraceStart = PawnLoc;
   TraceDest = PawnLoc - ( Vect(0, 0, 1 ) * CurrHeight ) - Vect(0, 0, 15 );

   // 추적해 내려가서 뭘 밟고 서 있는지 봅니다.
   TraceActor = Trace( out_HitLocation, out_HitNormal, TraceDest, TraceStart, false, TraceExtent, HitInfo, true );

   //DrawPersistentDebugLine( TraceStart, TraceDest, 255, 0, 0 );

   if( TraceActor != none )
   {
      // 이제 실제 소리를 재생합니다.
      ActuallyPlayFootStepSound( FootDown, HitInfo );
      MakeNoise( 0.1f, 'NOISETYPE_FootStep' );
   }
   // 아니면 아무것도 맞지 않은 공중에 있는 겁니다.
   else
   {
   //   Log( " 공중에 있다구!" );
   }

}

/**
* 이를 통해 밟고 서 있는 머티리얼이 뭔지 알아내고
* 올바른 발자국 소리를 재생합니다.
* 스폰하기에 적절한 효과를 찾을 때까지 피지컬 머티리얼 트리를 찾아봅니다.
* 찾지 못하면 해당 무기에 대해 .uc 파일에 코딩된 효과를
* 기본으로 삼습니다.
**/
function ActuallyPlayFootStepSound( int FootDown, TraceHitInfo HitInfo )
{
   local PhysicalMaterial ParentPhysMaterial;
   local SoundCue SC;
   local SoundCue FootStepSound;

   // XO5 HAX0R
   // 비속에 있으면 물발자국 소리를 냅니다.
   // 주: 현재 터레인은 추적용 머티리얼을 반환하지 않으니 직접 해 주는 수밖에요.
   //if( IsTimerActive( 'DropRainDropsOnToPawn' ) == TRUE )
   if( bShouldPlayWetFootSteps == TRUE )
   {
      Self.PlaySound( SoundCue'FootSteps.SoundCues.Footsteps_Marcus_Water', FALSE, TRUE );
      return;
   }


   // 피지컬 머티리얼이 없으면
   if( HitInfo.PhysMaterial != none )
   {
      FootStepSound = GetFootStepSound( HitInfo.PhysMaterial, FootDown );
   }
   else
   {
      // 머티리얼이 있는지 검사해 봅니다.
      // 머티리얼이 없으면 기본 PS_DefaultImpactEffect 를 사용해야 겠습니다.
      if( HitInfo.Material != none )
      {
         FootStepSound = GetFootStepSound( HitInfo.Material.PhysMaterial, FootDown );
      }
      else
      {
         // 항상 흙 발자국 소리인 "기본 발자국 소리"를 재생합니다.
         Self.PlaySound( SoundCue'FootSteps.SoundCues.Footsteps_Marcus_Dirt', FALSE, TRUE );
         return;
      }
   }


   // 이제 여기서, 원하는 특성에 없는 경우 "계층구조"를 찾아봐야 겠습니다.
   // 콘텐츠님께서 우리의 주린 배를 데이터로 채워주지 못하시는 경우,
   // 기본값을 재생시키는 예비 코드를 둬야 겠습니다.

   // 핒 머티리얼에 없는 경우,
   if( HitInfo.PhysMaterial != none )
   {
      ParentPhysMaterial = HitInfo.PhysMaterial.Parent;
   }
   // 부모 핒 머티리얼을 여기다 설정.
   else
   {
      // 머티리얼에 핒 머티리얼이 있는지 검사.
      if( HitInfo.Material.PhysMaterial != none )
      {
         ParentPhysMaterial = HitInfo.Material.PhysMaterial.Parent;
      }
      else
      {
         ParentPhysMaterial = none;
      }
   }


   // 부모가 null이거나 발자국 소리를 찾아서 (기본적으로 exception 케이스인)
   // break out(빠져나오기) 전까지는 트리를 순회하게 됩니다.
   // 근데 .uc 영역에는 exception이 없습니다.
   while( ( FootStepSound != none )
      && ( ParentPhysMaterial != none )
      )
   {
      // 부모의 데이터를 살펴봅니다.
      FootStepSound = GetFootStepSound( ParentPhysMaterial, FootDown );
      ParentPhysMaterial = ParentPhysMaterial.Parent;
   }


   // 머티리얼 기반 효과를 사용합니다.
   if( FootStepSound != none )
   {
      //Log( " 사운드 재생중: " $ FootStepSound );
      SC = FootStepSound;
   }
   // 기본 동작 수행
   else
   {
      //Log( " 기본 사운드 재생중" );
      SC = SoundCue'FootSteps.SoundCues.Footsteps_Marcus_Dirt';
   }

   Self.PlaySound( SC, FALSE, TRUE );
}


/**
* 현재 피지컬 머티리얼의 사운드가 사용가능한지 살펴봅니다.
**/
function SoundCue GetFootStepSound( PhysicalMaterial PMaterial, int FootDown )
{
   local SoundCue Retval;

   Retval = none;

   // 이제 Specific 속성이 존재하니
   // specificProperty 를 끄집어 내기 위한 함수를 호출해야 합니다.
   if( ( none != PMaterial )
      && ( none != PMaterial.PhysicalMaterialProperty )
      && ( none != WarPhysicalMaterialProperty(PMaterial.PhysicalMaterialProperty) )
      && ( none != WarPhysicalMaterialProperty(PMaterial.PhysicalMaterialProperty).WarPhysicalMaterialFootSteps )
      )
   {
      Retval = GetSpecificFootStepSound( WarPhysicalMaterialProperty(PMaterial.PhysicalMaterialProperty).WarPhysicalMaterialFootSteps, FootDown );
   }
   else
   {
      Retval = none;
   }

   return Retval;
}


/**
* 각 오브젝트가 이를 덮어쓰게 되며 전달된 오브젝트를 기반으로 한 데이터를
* 반환합니다. (예로 마커스에서 호출된 GetSpecificFootStepSound 는 마커스
* 발자국 소리를 찾아보며, 로커스트에서 호출되면 로커스트 소리를 찾아봅니다.)
**/
function SoundCue GetSpecificFootStepSound( WarPhysicalMaterialFootSteps FootStepSounds, int FootDown )
{
   local SoundCue Retval;

   // 가능한 연산 등을 수행합니다.
   Retval = None;

   return Retval;
}


예를 들어 BigOgre 클래스에서


function SoundCue GetSpecificFootStepSound( MyGamePhysicalMaterialFootSteps FootStepSounds, int FootDown )
{
   local SoundCue Retval;

   // 가능한 연산 등을 수행합니다.
   Retval = SoundCue'FootSteps.SoundCues.Footsteps_Player_Dirt';  // or make this a config and store the value in an .ini for editing by non programmers

   return Retval;
}