Facebook インテグレーション

class SocialMenu extends UDNMobileMenuScene;

/** Reference to the Facebook object */
var FacebookIntegration Facebook;

/** Are we currently authenticating with facebook? */
var bool bIsFBAuthenticating;

/** Have we already requested friends (because we don't want to send the request each time we wnt to view them) */
var bool bFriendsListPopulated;

/**
 * Called to initialize the menu and set up the scene
 */
function InitMenuScene(MobilePlayerInput PlayerInput, int ScreenWidth, int ScreenHeight, bool bIsFirstInitialization)
{
   Super.InitMenuScene(PlayerInput, ScreenWidth, ScreenHeight, bIsFirstInitialization);

   //initialize list
    List.InitMenuObject(PlayerInput, self, ScreenWidth, ScreenHeight, bIsFirstInitialization);

      //Get the reference to the Facebook object singleton
   Facebook = class'PlatformInterfaceBase'.static.GetFacebookIntegration();

   //Set the delegates to use for the authorization and GraphAPI request callbacks (we're not using any web requests)
   Facebook.AddDelegate(FID_AuthorizationComplete, OnFBAuthComplete);
   Facebook.AddDelegate(FID_FacebookRequestComplete, OnFBRequestComplete);

   //Set up some delegates for our menu objects (buttons, list, etc.)
   UDNMobileMenuButton(FindMenuObject("Authorize")).OnClick = AuthorizeFacebook;
   UDNMobileMenuButton(FindMenuObject("Friends")).OnClick = RequestFriends;
   List.OnChange = OnSelectFriend;
   List.OnCancel = HideFriendsList;
}

/**
 * Called when the menu is closed to clean up the scene
 */
function bool Closing()
{
   //Clear all the delegates when the menu closes
   Facebook.ClearDelegate(FID_AuthorizationComplete, OnFBAuthComplete);
   Facebook.ClearDelegate(FID_FacebookRequestComplete, OnFBRequestComplete);

   return super.Closing();
}

/**
 * Callback from the "Authorize" button's OnClick delegate - Performs the Facebook authorization process
 *
 * The parameters are not used - they are needed in this case simply because this is matching the OnClick delegate of the UDNMobileMenuButton
 */
function AuthorizeFacebook(UDNMobileMenuObject Sender, float X, float Y)
{
   //have we authorized previously?
   if (!Facebook.IsAuthorized())
   {
      //send for authorization
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Not Authorized";
      if (Facebook.Authorize() == true)
      {
         UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Is Authorizing";
         bIsFBAuthenticating = true;
      }
   }
   else
   {
      //set status as authorized
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Authorized";
   }
}

/**
 * Callback from the "Friends" button's OnClick delegate - Sends the Facebook GraphAPI request for the user's friends
 *
 * The parameters are not used - they are needed in this case simply because this is matching the OnClick delegate of the UDNMobileMenuButton
 */
function RequestFriends(UDNMobileMenuObject Sender, float X, float Y)
{
   //have we requested friends previously?
   if(!bFriendsListPopulated)
   {
      //send a request to graphAPI for friends list
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Requesting Friends List";
      Facebook.FacebookRequest("me/friends");
   }
   else
   {
      //show the previously populated friends list
      List.bIsHidden = false;
   }
}

/**
 * Callback from the list when an item is selected - Sets the text of the status bar label and closes the list
 *
 * @item - holds the name of the friend that was selected in the list
 */
function OnSelectFriend(int Idx, string Item, float X, float Y)
{
   UDNMobileMenuLabel(FindMenuObject("Status")).Caption = item;
   list.bIsHidden=true;
}

/**
 * Callback from the list when the "cancel" button is tapped - closes the list
 */
function HideFriendsList()
{
   list.bIsHidden=true;
}

/**
 * Callback from Authorize()
 *
 * @Result - Holds the data sent back from the authorization
 */
function OnFBAuthComplete(const out PlatformInterfaceDelegateResult Result)
{
   //set status to reflect successful authorization
   UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Auth Complete:"$Result.bSuccessful;
   bIsFBAuthenticating = false;
}

/**
 * Callback from GraphAPI requests
 *
 * @Result - Holds the data sent back from the request
 */
function OnFBRequestComplete(const out PlatformInterfaceDelegateResult Result)
{
   local JsonObject Root, FriendsArray, Friend;
   local int Index;

   if (Result.bSuccessful)
   {
      //set status as successful request
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Request Successful";

      //get the data from the request
      Root = class'JsonObject'.static.DecodeJson(Result.Data.StringValue);

      // get the friends array - top level is "data" = [friend,friend]
      FriendsArray = Root.GetObject("data");

      //output number of friends to status
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "You have " $ FriendsArray.ObjectArray.length $ " friends:";

      // loop over the friends
      for (Index = 0; Index < FriendsArray.ObjectArray.length; Index++)
      {
         // get a friend object
         Friend = FriendsArray.ObjectArray[Index];

         // output friend info
         UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Friend " $ Friend.GetStringValue("name") $ " has ID " $ Friend.GetStringValue("id");

         //add new friend to the list
         List.AddItem(Friend.GetStringValue("name"));
      }

      //display the list
      List.bIsHidden = false;
      bFriendsListPopulated = true;
   }
   else
   {
      //set status as unsuccessful request
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Request Unsuccessful";
   }
}

defaultproperties
{
   //Authorize button
   Begin Object Class=UDNMobileMenuButton Name=AuthorizeButton
      Tag="Authorize"
      Left=20
      Top=10
      Width=128
      Height=32
      TopLeeway=20
      Images(0)=Texture2D'PlatformInterfaceContent.fb_label'
        Images(1)=Texture2D'PlatformInterfaceContent.fb_label'
         ImagesUVs(0)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
         ImagesUVs(1)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
   End Object
   MenuObjects.Add(AuthorizeButton)

   //Friends button
   Begin Object Class=UDNMobileMenuButton Name=FriendsButton
      Tag="Friends"
      Left=20
      Top=52
      Width=128
      Height=32
      TopLeeway=20
      TextFont=Font'EngineFonts.SmallFont'
      Images(0)=Texture2D'PlatformInterfaceContent.fb_friends'
        Images(1)=Texture2D'PlatformInterfaceContent.fb_friends'
         ImagesUVs(0)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
         ImagesUVs(1)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
   End Object
   MenuObjects.Add(FriendsButton)

   //Status bar label
    Begin Object class=UDNMobileMenuLabel name=Label0
      Tag="Status"
      Height=32
      Width=480
      Left=0
      Top=288
      TextFont=Font'EngineFonts.SmallFont'
      BackgroundColors(0)=(R=0.0,G=0.0,B=0.0,A=1.0)
      BackgroundColors(1)=(R=0.0,G=0.0,B=0.0,A=1.0)
      CaptionColors(0)=(R=1.0,G=1.0,B=1.0,A=1.0)
      CaptionColors(1)=(R=1.0,G=1.0,B=1.0,A=1.0)
      Caption="Status"
   End Object
   MenuObjects.Add(Label0)

   //Friends list
   Begin Object class=UDNMobileMenuList name=List0
      Tag="FriendsList"
      bIsHidden=true
      bHasCancel=true
      Title="Friends"
   End Object
   List=List0
}

class SocialPC extends SimplePC;

event InitInputSystem()
{
   Super.InitInputSystem();

   MPI.OpenMenuScene(class'SocialMenu');
}

defaultproperties
{
   InputClass=class'GameFramework.MobilePlayerInput'
}

class SocialGame extends SimpleGame;

defaultproperties
{
   PlayerControllerClass=class'UDNGame.SocialPC'
}