虚幻的Logitech游戏LED SDK

概述

Logitech游戏LED SDK使得诸如游戏的应用能在受到支持的Logitech游戏鼠标和键盘中控制背景LED灯。

它可以很容易地通过使用DLLBind来整合进UDK游戏。

在本页面底部找到附加的SDK文件。

请参考Logitech SDK的Doc\LogitechGamingLEDSDK.pdf 来获得SDK功能的细节。

如有问题/意见，可email cjuncker@logitech.com, 或 lbyrne@logitech.com.

让LED SDK在您的UDK游戏中发挥作用

以下步骤展示了如何让Logitech SDK与随UDK下载时的 “UDKGame” 一起工作的信息。 请在您的游戏中按照此步骤设置使之能发挥作用。

步骤

• 下载UDK (http://www.unrealengine.com/udk/).
• 创建以下2个虚幻脚本文件，并复制它们到UDK的 Development\Src\MyMod\Classes 目录。

TestDLLGameInfo.uc

TestDLLGameInfo类扩展GameInfo;

defaultproperties
{
   PlayerControllerClass=class'TestDLLPlayerController'
}

TestDLLPlayerController.uc

class TestDLLPlayerController extends PlayerController
   DLLBind(LogitechLed);

dllimport final function bool LogiLedInit();
dllimport final function bool LogiLedSaveCurrentLighting(int deviceType);
dllimport final function bool LogiLedSetLighting(int deviceType, int redPercentage, int greenPercentage, int bluePercentage);
dllimport final function bool LogiLedRestoreLighting(int deviceType);
dllimport final function LogiLedShutdown();

exec function LogiInit()
{
   local bool ret;
   ret = LogiLedInit();

   say("LogiLedInit return is: " $ret);
}

exec function LogiSaveCurrentLighting(int deviceType)
{
   local bool ret;
   ret = LogiLedSaveCurrentLighting(deviceType);

   say("LogiLedSaveCurrentLighting return is: " $ret);
}

exec function LogiSetLighting(int deviceType, int redPercentage, int greenPercentage, int bluePercentage)
{
   local bool ret;
   ret = LogiLedSetLighting(deviceType, redPercentage, greenPercentage, bluePercentage);

   say("LogiLedSetLighting return is: " $ret);
}

exec function LogiRestoreLighting(int deviceType)
{
   local bool ret;
   ret = LogiLedRestoreLighting(deviceType);

   say("LogiLedRestoreLighting return is: " $ret);
}

exec function LogiShutdown()
{
   LogiLedShutdown();

   say("LogiLedShutdown done");
}

• 复制Logitech SDK的 Lib\x86\ LogitechLed.dll 到 UDK的 Binaries\Win32\UserCode
• 复制Logitech SDK的 Lib\x64\ LogitechLed.dll 到 UDK的 Binaries\Win64\UserCode
• 打开UDK的 UDKGame\Config\ DefaultEngineUDK.ini 文件以供编辑
  • 搜寻： ModEditPackages=MyMod
  • 移除行开头的 ;
• 启动 UDK的Binaries/UnrealFrontend.exe
  • 运行： 脚本->完全编译

从游戏中调用Logitech SDK的函数

用以下方式启动游戏：

• Binaries\Win32\UDK.exe dm-deck?game=MyMod.TestDLLGameInfo

当游戏在运行的时候，打开控制台（点击~），并输入： LogiInit ， 然后点击键。 您应该看到 "LogiLedInit return is: TRUE” （LogiLedInit返回值为真）的信息。

然后使用虚幻脚本文件定义的其他命令：

• LogiSetLighting
• LogiSaveCurrentLighting
• LogiRestoreLighting
• LogiShutdown

下载

• LogitechLEDSDK_1.01.005.1.zip: LogitechLEDSDK_1.02.002.1.zip